разные цвета шрифта "комментария"

[_невиДимка_]

Здравствуйте.
к сожалению, запись макроса не записывает действия по изменению размеров и цвета комментария. Примерный текст макроса:
iList = 1
While wList.Cells(iList, 5) <> Empty
Name = wList.Cells(iList, 1)
City = wList.Cells(iList, 2)
X = Val(wList.Cells(iList, 3))
Y = Val(wList.Cells(iList, 4))
Set Cell = wMap.Cells(Y + 1, X + 1)

On Error Resume Next
Cell.AddComment
Cell.Comment.Text Cell.Comment.Text & Name & " - " & City & Chr(10)
Cell.Comment.Visible = False

iList = iList + 1
Wend

Подскажите, пожалуйста, как добавлять комментарий определенного цвета, т.е. первую строку красного цвета, другую возможно синего или зеленого и т.д. и как установить размер шрифта.
Заранее спасибо.

[EducatedFool]

Код: Выделить всё

Sub [B]test_comment[/B]()
    Dim celll As Range, str As String: Set celll = Range("a1"): str = ""
    celll.ClearComments
    For i = 1 To 10: str = str & "Строка № " & i & vbLf: Next i
    celll.AddComment str
    
    With celll.Comment.Shape
        .Width = 200: .Height = 250
        .AutoShapeType = 16
        .Fill.ForeColor.SchemeColor = 11
        .Fill.TwoColorGradient msoGradientFromCenter, 2
    End With
    With celll.Comment.Shape.TextFrame
        For i = 1 To .Characters.Count
            letter = .Characters(Start:=i, Length:=1).Text
            .Characters(Start:=i, Length:=1).Font.Bold = IsNumeric(letter)
            .Characters(Start:=i, Length:=1).Font.Color = IIf(IsNumeric(letter), vbBlack, vbRed)
            If letter = "№" Then .Characters(Start:=i, Length:=1).Font.Size = 16
        Next
    End With
    celll.Comment.Visible = True
End Sub

Подробнее можно почитать здесь: http://msoffice.nm.ru/faq/macros/comments.htm

Пример во вложении:

[_невиДимка_]

EducatedFool
спасибо большое, буду разбираться
а по ссылке этой я все посмотрел, такого навороченного не нашел...